Apple Health in Excel

What you need

• An iPhone on iOS 15 or later with Apple Health. Apple Watch data comes along too.
• The HealthAPI app. Free for 2 days, no card needed. Then an optional 7-day free trial when you subscribe. The preview includes 25 requests a day. When the 2 days are up, AI apps and the API stop reading your data until you choose a plan in the app. Your synced data is kept for about 5 weeks, so subscribing picks up where you left off. Pro is $4.99 a month or $49.99 a year (100 requests a day); Developer is $9.99 a month or $99.99 a year (1,000 a day). Cancel anytime in the App Store.
• Excel for Windows: Microsoft 365, or Excel 2016 or later.

Which Excel works

Sources per version are in Microsoft's Power Query data sources table. On a Mac or in a browser, use the Google Sheets guide instead: same columns, refreshed every morning by a free script.

Set it up in 6 steps

1. 1

   Copy your API key

   Get HealthAPI from the App Store and let it sync. Then open Connect, tap Other tools and copy your key.
2. 2

   Open a blank query

   In Excel for Windows, choose Data, then Get Data, From Other Sources, Blank Query. The Power Query Editor opens.
3. 3

   Paste the query

   Select Advanced Editor on the Home tab, replace everything in it with the query below, put your key between the quotes on the Key line and select Done.
4. 4

   Connect as Anonymous

   If Power Query asks how to connect to healthapi.app, choose Anonymous and select Connect. Your key already travels in the header the query sends. A preview of your days appears.
5. 5

   Load it

   Give the query a name such as Health, then select Close & Load. The days land in a table on a new sheet.
6. 6

   Make it refresh itself

   Choose Data, then Queries & Connections. Right-click the query, choose Properties, and on the Usage tab tick Refresh data when opening the file. Tick Refresh every too if you keep the workbook open all day.

The query

It asks the weekly summary for this week and the 3 before it, takes the line for each day, and leaves out days that haven't happened yet. Paste all of it into the Advanced Editor.

let
    // Your HealthAPI key, from the app: Connect, then Other tools.
    // It is saved inside this workbook, so keep the file to yourself.
    Key = "PASTE_YOUR_KEY_HERE",
    // Weeks to show, this one included. Each refresh uses one request per week.
    Weeks = 4,

    Api = "https://healthapi.app/api/v1",
    Today = Date.From(DateTime.LocalNow()),

    // The ISO week a date falls in, such as "2026-W43".
    IsoWeek = (d as date) as text =>
        let
            Thursday = Date.AddDays(d, 3 - Date.DayOfWeek(d, Day.Monday)),
            WeekNo = Number.IntegerDivide(Date.DayOfYear(Thursday) - 1, 7) + 1
        in
            Text.From(Date.Year(Thursday)) & "-W" & Text.PadStart(Text.From(WeekNo), 2, "0"),

    // One week from HealthAPI: a record per day.
    GetWeek = (week as text) as list =>
        let
            Response = Web.Contents(Api, [
                RelativePath = "health/weekly-summary",
                Query = [week = week],
                Headers = [Authorization = "Bearer " & Key],
                ManualStatusHandling = {400, 402, 429}
            ]),
            Status = Value.Metadata(Response)[Response.Status],
            Body = Json.Document(Response)
        in
            if Status = 200 then Body[daily_breakdown]
            else error ("HealthAPI " & Text.From(Status) & ": " & Text.From(Body[detail]? ?? "")),

    Days = List.Combine(List.Transform({0 .. Weeks - 1}, each GetWeek(IsoWeek(Date.AddDays(Today, -7 * _))))),
    Rows = Table.FromRecords(List.Transform(Days, each [
        Date = Date.FromText([date]),
        Steps = [totals][steps],
        #"Sleep (h)" = [sleep_hours],
        #"Resting heart rate (bpm)" = [averages][resting_heart_rate_bpm],
        #"HRV (ms)" = [averages][hrv_ms],
        #"Active energy (kcal)" = [totals][active_energy_kcal],
        #"Exercise (min)" = [totals][exercise_time_min],
        Workouts = [workout_count],
        #"Workout time (min)" = [workout_duration_minutes]
    ])),
    UpToToday = Table.SelectRows(Rows, each [Date] <= Today),
    Sorted = Table.Sort(UpToToday, {{"Date", Order.Ascending}}),
    Typed = Table.TransformColumnTypes(Sorted, {
        {"Date", type date}, {"Steps", Int64.Type}, {"Sleep (h)", type number},
        {"Resting heart rate (bpm)", type number}, {"HRV (ms)", type number},
        {"Active energy (kcal)", type number}, {"Exercise (min)", type number},
        {"Workouts", Int64.Type}, {"Workout time (min)", type number}
    })
in
    Typed

Your key goes in the Authorization header, the same way as in every API example. Weeks sets how far back the table goes.

The columns

Today's row is the day so far. Days are in your HealthAPI account's timezone, the one your iPhone uses. The weekly summary has more per day, such as totals.distance_m and averages.spo2_pct; add a line to the Rows step to bring one in. Every field is in the API reference.

Refresh and requests

Both settings are on the Usage tab of the query's properties, as Microsoft describes in Refresh an external data connection. Refresh data when opening the file brings the table up to date each time you open it. Refresh every repeats it on a timer, only while the workbook is open in Excel.

Each refresh uses 4 requests. Refreshing every 60 minutes through a 10-hour day uses about 40, well inside Pro's 100. On the free preview's 25 a day, refresh on open only. HealthAPI has no push, so a refresh is how new data arrives: open the HealthAPI app first if you want last night's sleep in the table right away.

If something's wrong

Questions